BC23 - Fehlermeldung beim Ausgleich aufheben

Hallo zusammen,

wir habe die aktuelle BC23 Verison installiert und haben nun diese Fehlermeldung beim Kreditor-Posten-Ausgleich-aufheben - siehe Bilder.
Ich das auch wieder so ein Bug in der aktuellen BC23 Version ? VG Peter

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

Die Wahrscheinlichkeit ist hoch Ich würde auf jeden Fall auf das aktuelle Update 23.2 statt 23.0 gehen.

Update 23.2 for Microsoft Dynamics 365 Business Central (on-premises) 2023 Release Wave 2 (Application Build 23.2.14562, Platform Build 23.0.14532)

Hallo,

war da Skonto im Spiel?

Gruß Fiddi

Hallo

mal ganz "blönd" nachgefragt -> ist denn aktuell in der betroffenen Kreditornummer das Feld Kreditorenbuchungsgruppe gepflegt - also ungleich leer?

Sorry der Nachfrage, aber das geht aus dem Beitrag bisher ja nicht hervor...

VG Anke

Hallo zusammen,

ich "grabe" das Thema mal aus, weil es auch auf debitorischer Seite vorhanden ist.

Der Debugger gibt den Fehler in Codeunit 12 (Zeile 5132 in der Prozedur UnapplyCustLedgEntry) aus, weil das Feld Buchungsgruppe (Posting Group) im Datensatz Detail Cust. Ledger Entry leer ist.

image-20240104130830-1.png

Das Problem ist, dass dieses Feld in alten Versionen von Dynamics NAV nicht verfügbar ist und daher bei der Migration von Daten nach BC nicht gefüllt wird.

Ist einem MS Partner oder Kunden schon bekannt, ob MS hier eine Korrektur vornimmt?
Als Quickfix könnte ich mir vorstellen, über das Event OnOnUnapplyCustLedgEntryOnBeforeSecondLook die Detaillierten Debitorenposten mit der aktuellen Buchungsgruppe des Debitors zu befüllen.

Beste Grüße
Daniel

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

... Das Problem ist, dass dieses Feld in alten Versionen von Dynamics NAV nicht verfügbar ist und daher bei der Migration von Daten nach BC nicht gefüllt wird. ...

Gut zu wissen, dass es hier ein neues Feld gibt ! Aber dann müsste es doch nicht nur beid er Mogarton, sondern auch bei jedem neuen detaillierten Posten durch das System befüllt werden.

VG Anke

Korrekt. Das Feld wird in der aktuellen Version beim Erstellen eines detaillierten Postens gefüllt.
Ich habe jetzt mal einen schnellen Bugfix geschrieben, der uns das Aufheben von Ausgleichen wieder ermöglicht. Hier wird einfach die aktuelle Buchungsgruppe des Debitors/Kreditors in den detaillierten Posten übertragen, sofern das Feld leer war.
Alternativ könnte man die Buchungsgruppe auch aus den zugehörigen Kreditoren/Debitorenposten beziehen. Dann müsste der Code entsprechend angepasst werden.

Code:

codeunit 60750 "Bugfix Unapply"
{
    InherentPermissions = X;
    Permissions = tabledata "Detailed Cust. Ledg. Entry" = RM,
                    tabledata "Detailed Vendor Ledg. Entry" = RM;

    [EventSubscriber(ObjectType::Codeunit, 12, 'OnUnapplyVendLedgEntryOnBeforeSecondLook', '', false, false)]
    local procedure BugfixPostingGroupVendorOnUnapplyBeforeSecondLook(NextDtldLedgEntryNo: Integer; var DtldVendLedgEntry2: Record "Detailed Vendor Ledg. Entry")
    var
        Vendor: Record Vendor;
    begin
        if DtldVendLedgEntry2.FindSet() then
            repeat
                Vendor.Get(DtldVendLedgEntry2."Vendor No.");
                if DtldVendLedgEntry2."Posting Group" = '' then begin
                    DtldVendLedgEntry2."Posting Group" := Vendor."Vendor Posting Group";
                    DtldVendLedgEntry2.Modify();
                end;
            until DtldVendLedgEntry2.Next() = 0;
    end;

    [EventSubscriber(ObjectType::Codeunit, 12, 'OnOnUnapplyCustLedgEntryOnBeforeSecondLook', '', false, false)]
    local procedure BugfixPostingGroupCustomerOnUnapplyBeforeSecondLook(NextDtldLedgEntryNo: Integer; var DtldCustLedgEntry2: Record "Detailed Cust. Ledg. Entry")
    var
        Customer: Record Customer;
    begin
        if DtldCustLedgEntry2.FindSet() then
            repeat
                Customer.Get(DtldCustLedgEntry2."Customer No.");
                if DtldCustLedgEntry2."Posting Group" = '' then begin
                    DtldCustLedgEntry2."Posting Group" := Customer."Customer Posting Group";
                    DtldCustLedgEntry2.Modify();
                end;
            until DtldCustLedgEntry2.Next() = 0;
    end;
}


Gruß
Daniel

Danke für dei info!

Ich würde empfehlen" wenn leer, dann immer aus dem Debitor/Kreditor befüllen", denn der notwendige Wechsel einer Deb/Kre.-Buchungsgruppe ist in der Praxis nicht unüblich.

Zudem bleibt dann auch der Report "Deb. & Kred. Abstimmen" (ich habe gerade die ReportID nicht verfügbar und den BC Reportnamen kenne ich leider nicht ... wir haben noch NAV 2018) stimmig, da dieser immer auf der aktuellen Buchungsgruppe in Deb / Kred basiert.

VG Anke